class List

Sequence of values

my class List is Iterable does Positional { .. }

List stores items sequentially and potentially lazily.

Indexes into lists and arrays start at 0 by default.

You can assign to list elements if they are containers. Use Arrays to have every value of the list stored in a container.

Items, Flattening and Sigils

In Perl 6, assigning a List to a scalar variable does not lose information. The difference is that iteration generally treats a list (or any other list-like object, like a Parcel or an Array) inside a scalar as a single element.

my @a = 1, 2, 3;
for @a { }      # three iterations

my $s = @a;
for $s { }      # one iteration
for @a.item { } # one iteration
for $s.list { } # three iterations

Lists generally interpolate (flatten) unless they are accessed via an item (scalar) container.

my @a = 1, 2, 3;
my @flat   = @a, @a;           # six elements
my @nested = @a.item, @a.item; # two elements

.item can often be written as $( ... ), and on an array variable even as $@a.

Methods

routine elems

multi sub    elems($list)  returns Int:D
multi method elems(List:D:) returns Int:D

Returns the number of elements in the list.

routine end

multi sub    end($list)  returns Int:D
multi method end(List:D:) returns Int:D

Returns the index of the last element.

routine keys

multi sub    keys($list)  returns List:D
multi method keys(List:D:) returns List:D

Returns a list of indexes into the list (e.g., 0..(@list.elems-1)).

routine values

multi sub    values($list)  returns List:D
multi method values(List:D:) returns List:D

Returns a copy of the list.

routine kv

multi sub    kv($list)  returns List:D
multi method kv(List:D:) returns List:D

Returns an interleaved list of indexes and values. For example

<a b c>.kv

Returns

0, 'a', 1, 'b', 2, 'c'

routine pairs

multi sub    pairs($list)   returns List:D
multi method pairs(List:D:) returns List:D

Returns a list of pairs, with the indexes as keys and the list values as values.

<a b c>.pairs   # 0 => 'a', 1 => 'b', 2 => 'c'

routine join

multi sub    join($separator, *@list) returns Str:D
multi method join(List:D: $separator) returns Str:D

Treats the elements of the list as strings, interleaves them with $separator and concatenates everything into a single string.

Example:

join ', ', <a b c>;             # a, b, c

Note that the method form does not flatten sublists:

say (1, <a b c>).join('|');     # 1|a b c

routine map

multi sub    map(&code, *@elems) returns List:D
multi method map(List:D: &code) returns List:D

Invokes &code for each element and gathers the return values in another list and returns it. This happens lazily, i.e. &code is only invoked when the return values are accessed.

Examples:

> ('hello', 1, 22/7, 42, 'world').map: { .WHAT.perl }
Str Int Rat Int Str
> map *.Str.chars, 'hello', 1, 22/7, 42, 'world'
5 1 8 2 5

map inspects the arity of the code object, and tries to pass as many arguments to it as expected:

sub b($a, $b) { "$a before $b" };
say <a b x y>.map(&b).join(', ');   # a before b, x before y

iterates the list two items at a time.

Note that map does not flatten embedded lists and parcels, so

((1, 2), <a b>).map({ .join(',')})

passes (1, 2) and <a b> in turn to the block, leading to a total of two iterations and the result list "1,2", "a,b". See method flatmap for an alternative that flattens.

method flatmap

method flatmap(List:D: &code) returns List:D

Like map iterates over the elements of the invocant list, feeding each element in turn to the code reference, and assembling the return values from these invocations in a result list.

Unlike map it flattens non-itemized lists and parcels, so

say ((1, 2), <a b>).flatmap(&uc).join('|');     # 1|2|A|B

invokes uc|/type/Str#routine uc four times.

routine grep

multi sub    grep(Mu $matcher, *@elems) returns List:D
multi method grep(List:D:  Mu $matcher) returns List:D

Returns a lazy list of elements against which $matcher smart-matches. The elements are returned in the order in which they appear in the original list.

Examples:

> ('hello', 1, 22/7, 42, 'world').grep: Int
1 42
> grep { .Str.chars > 3 }, 'hello', 1, 22/7, 42, 'world'
hello 3.142857 world

routine grep-index

multi method grep-index(List:D: Mu $matcher) returns List:D

Returns a lazy list of indices against which the associated elements smart-match. The indices are returned in order.

routine first

multi sub    first(Mu $matcher, *@elems)
multi method first(List:D:  Mu $matcher)

Returns the first item of the list which smart-matches against $matcher, fails when no values match.

Examples:

say (1, 22/7, 42).first: * > 5;     # 42
say $f = ('hello', 1, 22/7, 42, 'world').first: Complex;
say $f.perl;                        #  Failure.new(exception => X::AdHoc.new(payload => "No values matched"))

routine first-index

multi method first-index(List:D: Mu $matcher)

Returns the first index against which $matcher smart-matches, or Nil if no match was found.

routine last-index

multi method last-index(List:D: Mu $matcher)

Returns the last index against which $matcher smart-matches, or Nil if no match was found.

routine classify

multi sub    classify(&mapper, *@values) returns Hash:D
multi method classify(List:D: &mapper)   returns Hash:D

Transforms a list of values into a hash representing the classification of those values according to a mapper; each hash key represents the classification for one or more of the incoming list values, and the corresponding hash value contains an array of those list values classified by the mapper into the category of the associated key.

Example:

say classify { $_ %% 2 ?? 'even' !! 'odd' }, (1, 7, 6, 3, 2);
    #-> even => 6 2, odd => 1 7 3
say ('hello', 1, 22/7, 42, 'world').classify: { .Str.chars };
    #-> 1 => 1, 2 => 42, 5 => hello world, 8 => 3.142857

method Bool

multi method Bool(List:D:) returns Bool:D

Returns True if the list has at least one element, and False for the empty list.

method Str

multi method Str(List:D:) returns Str:D

Stringifies the elements of the list and joins them with spaces (same as .join(' ')).

method Int

multi method Int(List:D:) return Int:D

Returns the number of elements in the list (same as .elems).

method Numeric

multi method Numeric(List:D:) return Int:D

Returns the number of elements in the list (same as .elems).

routine pick

multi sub    pick($count, *@list) returns List:D
multi method pick(List:D: $count = 1)

Returns $count elements chosen at random and without repetition from the invocant. If * is passed as $count, or $count is greater than or equal to the size of the list, then all elements from the invocant list are returned in a random sequence.

Examples:

say <a b c d e>.pick;           # b
b
say <a b c d e>.pick: 3;        # c a e
say  <a b c d e>.pick: *;       # e d a b c

routine roll

multi sub    roll($count, *@list) returns List:D
multi method roll(List:D: $count = 1)

Returns a lazy list of $count elements, each randomly selected from the list. Each random choice is made independently, like a separate die roll where each die face is a list element.

If * is passed to $count, returns a lazy, infinite list of randomly chosen elements from the original list.

Examples:

say <a b c d e>.roll;       # b
b
say <a b c d e>.roll: 3;    # c c e
say roll 8, <a b c d e>;    # b a e d a e b c

my $random_digits := (^10).roll(*);
say $random_digits[^15];    # 3 8 7 6 0 1 3 2 0 8 8 5 8 0 5

routine eager

multi method eager(List:D:) returns List:D
sub eager(*@elems) returns List:D

Evaluates all elements in the list eagerly, and returns them as a list. If a List signals that it is "known infinite", eager evaluation may stop at the point where the infinity is detected.

routine reverse

multi sub    reverse(*@list ) returns List:D
multi method reverse(List:D:) returns List:D

Returns a list with the same elements in reverse order.

Note that reverse always refers to reversing elements of a list; to reverse the characters in a string, use flip.

Examples:

say <hello world!>.reverse      #  world! hello
say reverse ^10                 # 9 8 7 6 5 4 3 2 1 0

routine rotate

multi sub    rotate(@list,  Int:D $n = 1) returns List:D
multi method rotate(List:D: Int:D $n = 1) returns List:D

Returns the list rotated by $n elements.

Examples:

<a b c d e>.rotate(2);   # <c d e a b>
<a b c d e>.rotate(-1);  # <e a b c d>

routine sort

multi sub    sort(*@elems)      returns List:D
multi sub    sort(&by, *@elems) returns List:D
multi method sort(List:D:)      returns List:D
multi method sort(List:D:, &by) returns List:D

Sorts the list, smallest element first. By default infix:<cmp> is used for comparing list elements.

If &by is provided, and it accepts two arguments, it is invoked for pairs of list elements, and should return Order::Increase, Order::Same or Order::Decrease.

If &by accepts only one argument, the list elements are sorted according to by($a) cmp by($b) . The return values of &by are cached, so that &by is only called once per list element.

Examples:

say (3, -4, 7, -1, 2, 0).sort;                  # -4 -1 0 2 3 7
say (3, -4, 7, -1, 2, 0).sort: *.abs;           # 0 -1 2 3 -4 7
say (3, -4, 7, -1, 2, 0).sort: { $^b leg $^a }; # 7 3 2 0 -4 -1

routine unique

multi sub    unique(*@values, :&as) returns List:D
multi method unique(List:D:,  :&as) returns List:D

Returns a list of unique values from the invocant/argument list, such that only the first occurrence of each duplicated value remains in the result list. unique uses the semantics of the === operator to decide whether two objects are the same. The order of the original list is preserved even as duplicates are removed.

Examples:

say <a a b b b c c>.unique    # a b c
say <a b b c c b a>.unique    # a b c

(Use squish instead if you know the input is sorted such that identical objects are adjacent.)

The optional :as parameter allows you to normalize/canonicalize the elements before unique-ing. The values are transformed for the purposes of comparison, but it's still the original values that make it to the result list:

Example:

say <a A B b c b C>.unique(:as(&lc))          # a B c

routine squish

multi sub    squish(*@values, :&as) returns List:D
multi method squish(List:D:,  :&as) returns List:D

Returns a list of values from the invocant/argument list where runs of more than one value are replaced with only the first instance. Like unique, squish uses the semantics of the === operator to decide whether two objects are the same. Unlike unique, this function only removes adjacent duplicates; identical values further apart are still kept. The order of the original list is preserved even as duplicates are removed.

Examples:

say <a a b b b c c>.squish  # a b c
say <a b b c c b a>.squish  # a b c b a

The optional :as parameter, just like with unique, allows values to be temporarily transformed before comparison.

routine reduce

multi sub    reduce(&with, *@elems)
multi method reduce(List:D: &with)

Applies &with to the first and the second value of the list, then to the result of that calculation and the third value and so on. Returns a single item generated that way.

Note that reduce is an implicit loop, and thus responds to next, last and redo statements.

Example:

say (1, 2, 3).reduce: * - *;    # -4

routine splice

multi sub    splice(@list,  $start, $elems?, *@replacement) returns List:D
multi method splice(List:D: $start, $elems?, *@replacement) returns List:D

Deletes $elems elements starting from index $start from the list, returns them and replaces them by @replacement. If $elems is omitted, all the elements starting from index $start are deleted.

Example:

my @foo = <a b c d e f g>;
say @foo.splice(2, 3, <M N O P>);       # c d e
say @foo;                               # a b M N O P f g

routine pop

multi sub    pop(List:D )
multi method pop(List:D:)

Removes and returns the last item from the list, fails for an empty list.

Example:

> my @foo = <a b>;
a b
> @foo.pop;
b
> pop @foo
a
> pop @foo
Element popped from empty list

routine push

multi sub    push(List:D, *@values) returns List:D
multi method push(List:D: *@values) returns List:D

Adds the @values to the end of the list, and returns the modified list. Fails for infinite lists.

Example:

my @foo = <a b c>;
@foo.push: 1, 3 ... 11;
say @foo;                   # a b c 1 3 5 7 9 11

routine shift

multi sub    shift(List:D )
multi method shift(List:D:)

Removes and returns the first item from the list. Fails for an empty list.

Example:

my @foo = <a b>;
say @foo.shift;     # a
say @foo.shift;     # b
say @foo.shift;     # Element shifted from empty list

routine unshift

multi sub    unshift(List:D, *@values) returns List:D
multi method unshift(List:D: *@values) returns List:D

Adds the @values to the start of the list, and returns the modified list. Fails if @values is infinite.

Example:

my @foo = <a b c>;
@foo.unshift: 1, 3 ... 11;
say @foo;                   # 1 3 5 7 9 11 a b c

routine combinations

multi method combinations (List:D: Int:D $of)          returns List:D
multi method combinations (List:D: Range:D $of = 0..*) returns List:D
multi sub    combinations ($n, $k)                     returns List:D

The Int variant returns all $of-combinations of the invocant list. For example

say .join('|') for <a b c>.combinations(2);

prints

a|b
a|c
b|c

because all the 2-combinations of 'a', 'b', 'c' are ['a', 'b'], ['a', 'c'], ['b', 'c'].

The Range variant combines all the individual combinations into a single list, so

say .join('|') for <a b c>.combinations(2..3);

prints

a|b
a|c
b|c
a|b|c

because that's the list of all 2- and 3-combinations.

The subroutine form combinations($n, $k) is equivalent to (^$n).combinations($k), so

.say for combinations(4, 2)

prints

0 1
0 2
0 3
1 2
1 3
2 3

routine permutations

multi method permutations(List:D:) returns List:D
multi sub    permutations($n)      returns List:D

Returns all possible permutations of a list as a list of arrays. So

say .join('|') for <a b c>.permutations

prints

a|b|c
a|c|b
b|a|c
b|c|a
c|a|b
c|b|a

permutations treats all list elements as distinguishable, so (1, 1, 2).permutations still returns a list of 6 elements, even though there are only three distinct permutations.

The subroutine form permutations($n) is equivalent to (^$n).permutations, so

.say for permutations 3;

prints

1 2 3
1 3 2
2 1 3
2 3 1
3 1 2
3 2 1

method rotor

method rotor(*@cycle, Bool() :$partial)

Returns a list of lists, where each sublist is made up of elements of the invocant.

In the simplest case, @cycle contains just one integer, in which case the invocant list is split into sublists with as many elements as the integer specifies. If :$partial is True, the final chunk is included even if it doesn't satisfy the length requirement:

say ('a'..'h').rotor(3).join('|');              # a b c|d e f
say ('a'..'h').rotor(3, :partial).join('|');    # a b c|d e f|g h

If the element of @cycle is a /type/Pair instead, the key of the pair specifies the length of the return sublist, and the value the gap between sublists; negative gaps produce overlap:

say ('a'..'h').rotor(2 => 1).join('|');         # a b|d e|g h
say ('a'..'h').rotor(3 => -1).join('|');        # a b c|c d e|e f g

If @cycle contains more than element, rotor cycles through it to find the number of elements for each sublist:

say ('a'..'h').rotor(2, 3).join('|');           # a b|c d e|f g
say ('a'..'h').rotor(1 => 1, 3).join('|');      # a|c d e|f

Combining multiple cycles and :partial also works:

say ('a'..'h').rotor(1 => 1, 3 => -1, :partial).join('|');
                                                # a|c d e|e|g h

Note that assigning the list of lists returned from rotor to a variable will flatten to an Array:

my @maybe_lol = ('a'..'h').rotor(2 => 1);
@maybe_lol.perl.say;   #-> ["a", "b", "d", "e", "g", "h"]<>

Which probably isn't what one wanted, since the rotor-ed output looks like this:

say ('a'..'h').rotor(2 => 1).perl; #-> (("a", "b"), ("d", "e"), ("g", "h"))

To force a List of Lists to be returned, bind the output instead of assigning it:

my @really_lol := ('a'..'h').rotor(2 => 1);
@really_lol.perl.say;   #-> (("a", "b"), ("d", "e"), ("g", "h"))

routine zip

sub zip(List:D:, List:D:, ...) returns List:D

Zip two or more lists together by interleaving their elements. If the lists have different lengths, then the lists are zipped to the length of the shortest list; elements of the longer list(s) are discarded.

In order to support parallel iteration over multiple arrays, Perl 6 has a zip function that builds a list of Parcel objects from the elements of two or more arrays. In ordinary list context this behaves as a list of Captures and automatically flattens.

for zip(@names; @codes) -> $name, $zip {
    say "Name: $name;   Zip code: $zip";
}

zip has an infix synonym, the Z operator.

In an explicitly multidimensional list context, however, the sequences turn into subarrays, and each element would then have to be unpacked by the signature:

for lol(zip(@names; @codes)) -> [$name, $zip] {
    say "Name: $name;   Zip code: $zip";
}

By default the zip function reads to the end of the shortest list, but a short list may always be extended arbitrarily by putting * after the final value, which replicates the final value as many times as necessary. If instead of supplying a default value for short lists, you just wish to skip missing entries, use roundrobin instead:

for roundrobin(@queue1; @queue2; @queue3) -> $next {
    ...
}

sub roundrobin

multi roundrobin(List:D: --> Parcel)

roundrobin is very similar to zip. The difference is that roundrobin will not stop on lists that run out of elements but simply skip any undefined value:

my @a = 1;
my @b = 1..2;
my @c = 1..3;
for roundrobin(@a; @b; @c) -> $x { $x.say }

will display the following values: 1, 1, 1, 2, 2, 3

Type graph

Below you should see a clickable image showing the type relations for List that links to the documentation pages for the related types. If not, try the PNG version instead.

perl6-type-graph List List Iterable Iterable List->Iterable Cool Cool List->Cool Positional Positional List->Positional Mu Mu Any Any Any->Mu Iterable->Any Cool->Any Backtrace Backtrace Backtrace->List Array Array Array->List LoL LoL LoL->List

Routines supplied by role Positional

List does role Positional, which provides the following methods:

method of

method of()

Returns the type constraint for elements of the positional container. Defaults to Mu.

Routines supplied by class Cool

List inherits from class Cool, which provides the following methods:

routine abs

method abs()
sub abs(Numeric() $x)

Coerces the invocant (or in the sub form, the argument) to Numeric and returns the absolute value (that is, a non-negative number).

say (-2).abs;       # 2
say abs "6+8i";     # 10

method conj

method conj()

Coerces the invocant to Numeric and returns the complex conjugate (that is, the number with the sign of the imaginary part negated).

say (1+2i).conj;        # 1-2i

routine sqrt

method sqrt()
sub sqrt(Numeric(Cool) $x)

Coerces the invocant to Numeric (or in the sub form, the argument) and returns the square root, that is, a non-negative number that, when multiplied with itself, produces the original number.

say 4.sqrt;             # 2
say sqrt(2);            # 1.4142135623731

method sign

method sign()

Coerces the invocant to Numeric and returns its sign, that is, 0 if the number is 0, 1 for positive and -1 for negative values.

say 6.sign;             # 1
say (-6).sign;          # -1
say "0".sign;           # 0

method rand

method rand()

Coerces the invocant to Num and returns a pseudo-random value between zero and the number.

say 1e5.rand;           # 33128.495184283

routine sin

method sin()
sub sin(Numeric(Cool))

Coerces the invocant (or in the sub firm, the argument) to Numeric, interprets it as radians, returns its sine.

say sin(0);             # 0
say sin(pi/4);          # 0.707106781186547
say sin(pi/2);          # 1

Note that Perl 6 is no computer algebra system, so sin(pi) typically does not produce an exact 0, but rather a very small floating-point number.

routine asin

sub asin(Numeric(Cool))
method asin()

Coerces the invocant (or in the sub firm, the argument) to Numeric, and returns its arc-sine in radians.

say 0.1.asin;               # 0.10016742116156

routine cos

method cos()
sub cos(Numeric(Cool))

Coerces the invocant (or in sub form, the argument) to Numeric, interprets it as radians, returns its sine.

say 0.cos;                  # 1
say pi.cos;                 # -1
say cos(pi/2);              # 6.12323399573677e-17

routine acos

method acos()
sub acos(Numeric(Cool))

Coerces the invocant (or in sub form, the argument) to Numeric, and returns its arc-cosine in radians.

routine tan

method tan()
sub tan(Numeric(Cool))

Coerces the invocant (or in sub form, the argument) to Numeric, interprets it as radians, returns its tangens.

routine atan

method atan()
sub atan(Numeric(Cool))

Coerces the invocant (or in sub form, the argument) to Numeric, and returns its arc-tangens in radians.

routine atan2

method atan2($y = 1e0)
sub atan2(Numeric() $x, Numeric() $y = 1e0)

Coerces the arguments (including the invocant in the method form) to Numeric, and returns their two-argument arc-tangens in radians.

method sec

method sec()
sub sec(Numeric(Cool))

Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its secans, that is, the reciprocal of its cosine.

routine asec

method asec()
sub asec(Numeric(Cool))

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-secans in radians.

routine cosec

method cosec()
sub cosec(Numeric(Cool))

Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its cosecans, that is, the reciprocal of its sine.

routine acosec

method acosec()
sub acosec(Numeric(Cool))

Coerces the invocant (or in sub form, its argument) to Numeric, and returns its arc-cosecans in radians.

routine cotan

method cotan()
sub cotan(Numeric(Cool))

Coerces the invocant (or in sub form, its argument) to Numeric, interprets it as radians, returns its cotangens, that is, the reciprocal of its tangens.

routine acotan

method acotan()
sub acotan(Numeric(Cool))

Coerces the invocant (or in method form, its argument) to Numeric, and returns its arc-cotangens in radians.

routine sinh

method sinh()
sub sinh(Numeric(Cool))

Coerces the invocant (or in method form, its argument) to Numeric, and returns its Sine hyperbolicus.

routine asinh

method asinh()
sub asinh(Numeric(Cool))

Coerces the invocant (or in method form, its argument) to Numeric, and returns its Inverse Sine hyperbolicus.

routine cosh

method cosh()
sub cosh(Numeric(Cool))

Coerces the invocant (or in method form, its argument) to Numeric, and returns its Cosine hyperbolicus.

routine acosh

method acosh()
sub acosh(Numeric(Cool))

Coerces the invocant (or in method form, its argument) to Numeric, and returns its Inverse Cosine hyperbolicus.

routine tanh

method tanh()
sub tanh(Numeric(Cool))

Coerces the invocant (or in method form, its argument) to Numeric, and returns its Tangens hyperbolicus.

routine atanh

method atanh()
sub atanh(Numeric(Cool))

Coerces the invocant (or in method form, its argument) to Numeric, and returns its Inverse tangens hyperbolicus.

routine log

multi method log(Cool:D: Cool:D $base?)
multi sub log(Numeric(Cool) $number, Numeric(Cool) $base?)

Coerces the arguments (including the invocant in the method form) to Numeric, and returns its Logarithm to base $base, or to base e (Euler's Number) if no base was supplied (Natural logarithm.

say (e*e).log;                      # 2

routine log10

multi method log10()
multi sub log10(Cool(Numeric))

Coerces the invocant (or in the sub form, the invocant) to Numeric, and returns its Logarithm to base 10, that is, a number that approximately produces the original number when raised to the power of 10.

say log10(1001);                    # 3.00043407747932

method exp

multi method exp(Cool:D: Cool:D $base?)
multi sub exp(Cool:D $pow, Cool:D $base?)

Coerces the arguments (including the invocant in the method from) to Numeric, and returns $base raised to the power of the first number. If no $base is supplied, e (Euler's Number) is used.

say 0.exp;      # 1
say 1.exp;      # 2.71828182845905
say 10.exp;     # 22026.4657948067

routine round

multi method round(Cool:D: $unit = 1)
multi sub round(Numeric(Cool))

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it to the unit of $unit. If $unit is 1, rounds to the nearest integer.

say 1.7.round;          # 2
say 1.07.round(0.1);    # 1.1
say 21.round(10);       # 20

routine floor

multi method floor
multi sub floor(Numeric(Cool))

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it downwards to the nearest integer.

say "1.99".floor;       # 1
say "-1.9".floor;       # -2
say 0.floor;            # 0

routine ceiling

multi method ceiling
multi sub ceiling(Numeric(Cool))

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it upwards to the nearest integer.

say "1".ceiling;        # 1
say "-0.9".ceiling;     # 0
say "42.1".ceiling;     # 43

routine truncate

multi method truncate()
multi sub truncate(Numeric(Cool))

Coerces the invocant (or in sub form, its argument) to Numeric, and rounds it towards zero.

say 1.2.truncate        # 1
say truncate -1.2;      # -1

routine ord

method ord()
sub ord(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns the Unicode code point, number of the code point.

say 'a'.ord;            # 65

The inverse operation is chr.

Mnemonic: returns an ordinal number

routine chr

method chr()
sub chr(Int(Cool))

Coerces the invocant (or in sub form, its argument) to Int, interprets it as a Unicode code points, and returns a string made of that code point.

say '65'.chr;       # A

The inverse operation is ord.

Mnemonic: turns an integer into a character.

routine chars

method chars()
sub chars(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns the number of characters in the string. Characters should actually be grapheme clusters, though current implementations erroneously count codepoints instead.

say 'møp'.chars;    # 3

routine codes

method codes()
sub codes(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns the number of Unicode code points.

say 'møp'.codes;    # 3

routine flip

method flip()
sub flip(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns a reversed version.

say 421.flip;       # 124

routine trim

method trim()
sub trim(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns the string with both leading and trailing whitespace stripped.

my $stripped = '  abc '.trim;
say "<$stripped>";          # <abc>

routine trim-leading

method trim-leading()
sub trim-leading(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns the string with leading whitespace stripped.

my $stripped = '  abc '.trim-leading;
say "<$stripped>";          # <abc >

routine trim-trailing

method trim-trailing()
sub trim-trailing(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns the string with trailing whitespace stripped.

my $stripped = '  abc '.trim-trailing;
say "<$stripped>";          # <  abc>

routine lc

method lc()
sub lc(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns it case-folded to lower case.

say "ABC".lc;       # abc

routine uc

method uc()
sub uc(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns it case-folded to upper case (capital letters).

say "Abc".uc;       # ABC

routine tc

method tc()
sub tc(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the first letter case-folded to title case (or where not available, upper case).

say "abC".tc;       # AbC

routine tclc

method tclc()
sub tclc(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the first letter case-folded to title case (or where not available, upper case), and the rest of the string case-folded to lower case..

say 'abC'.tclc;     # Abc

routine wordcase

method wordcase(:&filter = &tclc, Mu :$where = True)
sub wordcase(Str(Cool) $input, :&filter = &tclc, Mu :$where = True)

Coerces the invocant (or in sub form, the first argument) to Str, and filters each word that smart-matches against $where through the &filter. With the default filter (first character to upper case, rest to lower) and matcher (which accepts everything), this title-cases each word:

say "perl 6 programming".wordcase;      # Perl 6 Programming

With a matcher:

say "have fun working on perl".wordcase(:where({ .chars > 3 }));
                                        # Have fun Working on Perl

With a customer filter too:

say "have fun working on perl".wordcase(:filter(&uc), :where({ .chars > 3 }));
                                        # HAVE fun WORKING on PERL

routine uniname

method uniname() returns Str
sub uniname(Str(Cool) returns Str

Interprets the invocant / first argument as a /type/Str, and returns the Unicode codepoint name of the first character.

routine chop

method chop()
sub chop(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the last character removed.

say 'perl'.chop;                        # per

routine chomp

method chomp()
sub chomp(Str(Cool))

Coerces the invocant (or in sub form, its argument) to Str, and returns it with the last character removed, if it is a logical newline.

say 'ab'.chomp.chars;                   # 2
say "a\n".chomp.chars;                  # 1

routine substr

method substr($from, $chars?)
sub substr(Str(Cool) $str, $from, $chars?)

Coerces the invocant (or in the sub form, the first argument) to Str, and returns the string starting from offset $from. If $chars is supplied, at most $chars characters are returned.

say 'zenith'.substr(2);         # nith
say 'zenith'.substr(0, 3);      # zen

# works on non-strings too:
say 20151224.substr(6);         # 24

# sub form:
say substr "zenith", 0, 3;      # zen

If the $from parameter is a Callable, it is called with the number of chars in the string as argument. This allows easy indexing relative to the end:

say 20151224.substr(*-2);       # 24

routine ords

method ords()
sub ords(Str(Cool) $str)

Coerces the invocant (or in the sub form, the first argument) to Str, and returns a list of Unicode codepoints for each character.

say "Perl 6".ords;              # 80 101 114 108 32 54
say ords 10;                    # 49 48

This is the list-returning version of ord. The inverse operation in chrs.

routine chrs

method chrs()
sub chrs(*@codepoints) return Str:D

Coerces the invocant (or in the sub form, the argument list) to a list of integers, and returns the string created by interpreting each integer as a Unicode codepoint, and joining the characters.

say <80 101 114 108 32 54>.chrs;    # Perl 6

This is the list-input version of chr. The inverse operation is ords.

routine split

multi method split(  Str:D $delimiter, $limit = Inf, :$all)
multi method split(Regex:D $delimiter, $limit = Inf, :$all)
multi sub    split(  Str:D $delimiter, Str(Cool) $input, $limit = Inf, :$all)
multi sub    split(Regex:D $delimiter, Str(Cool) $input, $limit = Inf, :$all)

Coerces the invocant (or in the sub form, the second argument) to Str, and splits it into pieces based on delimiters found in the string.

If $delimiter is a string, it is searched for literally and not treated as a regex.

If the named parameter :all is passed, the matches from $delimiter are included in the result list.

Note that unlike in Perl 5, empty chunks are not removed from the result list. If you want that behavior, consider using comb instead.

say split(';', "a;b;c").perl;          # ("a", "b", "c").list
say split(';', "a;b;c", :all).perl;    # ("a", ";", "b", ";", "c").list
say split(';', "a;b;c", 2).perl;       # ("a", "b;c").list
say split(';', "a;b;c", 2, :all).perl; #("a", ";", "b;c").list

say split(';', "a;b;c,d").perl;        # ("a", "b", "c,d").list
say split(/\;/, "a;b;c,d").perl;       # ("a", "b", "c,d").list
say split(/<[;,]>/, "a;b;c,d").perl;   # ("a", "b", "c", "d").list

routine lines

method lines()
sub lines(Str(Cool))

Coerces the invocant (and in sub form, the argument) to Str, decomposes it into lines (with the newline characters stripped), and returns the list of lines.

say lines("a\nb\n").join('|');          # a|b
say "some\nmore\nlines".lines.elems;    # 3

This method can be used as part of an IO::Path to process a file line-by-line, since IO::Path objects inherit from Cool, e.g.:

for 'huge-csv'.IO.lines -> $line {
        # Do something with $line
}

# or if you'll be processing later
my @lines = 'huge-csv'.IO.lines;

method words

method words(Int() $limit)

Coerces the invocant to Str, and returns a list of words that make up the string (and if $limit is supplied, only the first $limit words).

say 'The quick brown fox'.words.join('|');      # The|quick|brown|fox
say 'The quick brown fox'.words(2).join('|');   # The|quick

Only whitespace counts as word boundaries

say "isn't, can't".words.join('|');             # isn't,|can't

routine comb

multi method comb(Regex $matcher, $limit = *) returns List:D
multi sub comb(Regex $matcher, Str(Cool) $input, $limit = *) returns List:D

Returns all (or if supplied, at most $limit) matches of the invocant (method form) or the second argument (sub form) against the Regex as a list of strings.

say "6 or 12".comb(/\d+/).join(", ");           # 6, 12

routine index

multi sub    index(Str(Cool) $s, Str:D $needle, Int(Cool) $startpos = 0) returns Int
multi method index(Str(Cool) $needle, Int(Cool) $startpos = 0) returns Int

Coerces the first two arguments (in method form, also counting the invocant) to Str, and searches for $needle in the string starting from $startpos. It returns the offset into the string where $needle was found, and an undefined value if it was not found.

See the documentation in type Str for examples.

routine rindex

multi sub    rindex(Str(Cool) $haystack, Str(Cool) $needle, Int(Cool) $startpos = $haystack.chars)
multi method rindex(Str(Cool) $haystack: Str(Cool) $needle, Int(Cool) $startpos = $haystack.chars)

Coerces the first two arguments (including the invocant in method form) to Str and $startpos to Int, and returns the last position of $needle in $haystack not after $startpos. Returns an undefined value if $needle wasn't found.

See the documentation in type Str for examples.

routine roots

multi method roots(Int(Cool) $n)
multi sub roots(Numeric(Cool) $x, Int(Cool) $n)

Coerces the first argument (and in method form, the invocant) to Numeric and the second ($n) to Int, and produces a list of $n Complex $n-roots, which means numbers that, raised to the $nth power, approximately produce the original number.

For example

my $original = 16;
my @roots = $original.roots(4);
say @roots;

for @roots -> $r {
    say abs($r ** 4 - $original);
}

produces this output:

2+0i 1.22464679914735e-16+2i -2+2.44929359829471e-16i -3.67394039744206e-16-2i
1.77635683940025e-15
4.30267170434156e-15
8.03651692704705e-15
1.04441561648202e-14

method IO

method IO() returns IO::Path:D

Coerces the invocant to IO::Path.

.say for '.'.IO.dir;        # gives a directory listing

Routines supplied by class Any

List inherits from class Any, which provides the following methods:

method ACCEPTS

multi method ACCEPTS(Any:D: Mu $other)

Returns True if $other === self (i.e. it checks object identity).

Many built-in types override this for more specific comparisons

method any

method any() returns Junction:D

Interprets the invocant as a list and creates an any-Junction from it.

say so 2 == <1 2 3>.any;        # True
say so 5 == <1 2 3>.any;        # False

method all

method all() returns Junction:D

Interprets the invocant as a list and creates an all-Junction from it.

say so 1 < <2 3 4>.all;         # True
say so 3 < <2 3 4>.all;         # False

method one

method one() returns Junction:D

Interprets the invocant as a list and creates an one-Junction from it.

say so 1 == (1, 2, 3).one;      # True
say so 1 == (1, 2, 1).one;      # False

method none

method none() returns Junction:D

Interprets the invocant as a list and creates an none-Junction from it.

say so 1 == (1, 2, 3).none;     # False
say so 4 == (1, 2, 3).none;     # True

method list

Interprets the invocant as a list, and returns that List.

say so 42.list.^name;           # List
say so 42.list.elems;           # 1

method flat

Interprets the invocant as a list, flattens it, and returns that list.

say ((1, 2), (3)).elems;        # 2
say ((1, 2), (3)).flat.elems;   # 3

method eager

Interprets the invocant as a list, evaluates it eagerly, and returns that list.

say (1..10).eager;              # 1 2 3 4 5 6 7 8 9 10

method elems

Interprets the invocant as a list, and returns the number of elements in the list.

say 42.elems;                   # 1
say <a b c>.elems;              # 3

method end

Interprets the invocant as a list, and returns the last index of that list.

say 6.end;                      # 0
say <a b c>.end;                # 2

method pairup

method pairup() returns List

Interprets the invocant as a list, and constructs a list of pairs from it, in the same way that assignment to a Hash does. That is, it takes two consecutive elements and constructs a pair from them, unless the item in the key position already is a pair (in which case the pair is passed is passed through, and the next list item, if any, is considered to be a key again).

say (a => 1, 'b', 'c').pairup.perl;     # ("a" => 1, "b" => "c").list

sub exit

sub exit(Int() $status = 0)

Exits the current process with return code $status.

Routines supplied by class Mu

List inherits from class Mu, which provides the following methods:

routine defined

multi sub    defined(Mu) returns Bool:D
multi method defined()   returns Bool:D

Returns False on the type object, and True otherwise.

say Int.defined;                # False
say 42.defined;                 # True

Very few types (like Failure) override defined to return False even for instances:

sub fails() { fail 'oh noe' };
say fails().defined;            # False

routine Bool

multi sub    Bool(Mu) returns Bool:D
multi method Bool()   returns Bool:D

Returns False on the type object, and True otherwise.

Many built-in types override this to be False for empty collections, the empty string or numerical zeros

say Mu.Bool;                    # False
say Mu.new.Bool;                # True
say [1, 2, 3].Bool;             # True
say [].Bool;                    # False
say { 'hash' => 'full'}.Bool;   # True
say {}.Bool;                    # False

method Str

multi method Str()   returns Str

Returns a string representation of the invocant, intended to be machine readable. Method Str warns on type objects, and produces the empty string.

say Mu.Str;                     #!> use of uninitialized value of type Mu in string context

routine gist

multi sub    gist(Mu) returns Str
multi method gist()   returns Str

Returns a string representation of the invocant, optimized for fast recognition by humans.

The default gist method in Mu re-dispatches to the perl method for defined invocants, and returns the type name in parenthesis for type object invocants. Many built-in classes override the case of instances to something more specific.

gist is the method that say calls implicitly, so say $something and say $something.gist generally produce the same output.

say Mu.gist;        # (Mu)
say Mu.new.gist;    # Mu.new()

routine perl

multi sub    perl(Mu) returns Str
multi method perl()   returns Str

Returns a Perlish representation of the object (i.e., can usually be re-evaluated with EVAL to regenerate the object). The exact output of perl is implementation specific, since there are generally many ways to write a Perl expression that produces a particular value

method clone

method clone(*%twiddles)

Creates a shallow clone of the invocant. If named arguments are passed to it, their values are used in every place where an attribute name matches the name of a named argument.

class Point2D {
    has ($.x, $.y);
    multi method gist(Point2D:D:) {
        "Point($.x, $.y)";
    }
}

my $p = Point2D.new(x => 2, y => 3);

say $p;                     # Point(2, 3)
say $p.clone(y => -5);      # Point(2, -5)

method new

multi method new(*%attrinit)

Default method for constructing (create + initialize) new objects of a class. This method expects only named arguments which are then used to initialize attributes with accessors of the same name.

Classes may provide their own new method to override this default.

new triggers an object construction mechanism that calls submethods named BUILD in each class of an inheritance hierarchy, if they exist. See the documentation on object construction for more information.

method bless

method bless(*%attrinit) returns Mu:D

Lower-level object construction method than new.

Creates a new object of the same type as the invocant, uses the named arguments to initialize attributes, and returns the created object.

You can use this method when writing custom constructors:

class Point {
    has $.x;
    has $.y;
    multi method new($x, $y) {
        self.bless(:$x, :$y);
    }
}
my $p = Point.new(-1, 1);

(Though each time you write a custom constructor, remember that it makes subclassing harder).

method CREATE

method CREATE() returns Mu:D

Allocates a new object of the same type as the invocant, without initializing any attributes.

say Mu.CREATE.defined;  # True

method print

multi method print() returns Bool:D

Prints value to $*OUT after stringification using .Str method without adding a newline at end.

"abc\n".print;          # abc

method say

multi method say() returns Bool:D

Prints value to $*OUT after stringification using .gist method with newline at end.

say 42;                 # 42

method ACCEPTS

multi method ACCEPTS(Mu:U: $other)

ACCEPTS is the method that smart matching with the infix ~~ operator and given/when invokes on the right-hand side (the matcher).

The Mu:U multi performs a type check. Returns True if $other conforms to the invocant (which is always a type object or failure).

say 42 ~~ Mu;           # True
say 42 ~~ Int;          # True
say 42 ~~ Str;          # False

Note that there is no multi for defined invocants; this is to allow autothreading of junctions, which happens as a fallback mechanism when no direct candidate is available to dispatch to.

method WHICH

multi method WHICH() returns ObjAt:D

Returns an object of type ObjAt which uniquely identifies the object. Value types override this method which makes sure that two equivalent objects return the same return value from WHICH.

say 42.WHICH eq 42.WHICH;       # True

method WHERE

method WHERE() returns Int

Returns an Int representing the memory address of the object.

method WHY

multi method WHY()

Returns the attached Pod value. For instance,

    sub cast(Spell $s)
    #= Initiate a specified spell normally
    #= (do not use for class 7 spells)
    {
	do-raw-magic($s);
    }
    say &cast.WHY;

prints

Initiate a specified spell normally (do not use for class 7 spells)

See the documentation specification for details about attaching Pod to variables, classes, functions, methods, etc.

trait is export

multi sub trait_mod:<is>(Mu:U \type, :$export!)

Marks a type as being exported, that is, available to external users.

my class SomeClass is export { }

A user of a module or class automatically gets all the symbols imported that are marked as is export.

method take

method take()

Takes the given item and passes it to the enclosing gather block.

#| randomly select numbers for lotto
my $num-selected-numbers = 6;
my $max-lotto-numbers = 49;
gather for ^$num-selected-numbers {
    take (1 .. $max-lotto-numbers).pick(1);
}.say;    #-> 32 22 1 17 32 9  (for example)

method so

method so()

Returns a Bool value representing the logical non-negation of an expression. One can use this method similarly to the English sentence: "If that is so, then do this thing". For instance,

my @args = <-a -e -b -v>;
my $verbose-selected = any(@args) eq '-v' | '-V';
if $verbose-selected.so {
    say "Verbose option detected in arguments";
} #-> Verbose option detected in arguments

method not

method not()

Returns a Bool value representing the logical negation of an expression. Thus it is the opposite of so.

my @args = <-a -e -b>;
my $verbose-selected = any(@args) eq '-v' | '-V';
if $verbose-selected.not {
    say "Verbose option not present in arguments";
} #-> Verbose option not present in arguments

Since there is also a prefix version of not, the above code reads better like so:

my @args = <-a -e -b>;
my $verbose-selected = any(@args) eq '-v' | '-V';
if not $verbose-selected {
    say "Verbose option not present in arguments";
} #-> Verbose option not present in arguments